POV Ray 3.7 code
//=======================================================
// Newton's method 2D set as a whole (full and carved)
// (POV-Ray point by point plot)
//=======================================================

#include "colors.inc"  // Standard Color definitions
#include "glass.inc"   //  Glass pigment effect
#include "metals.inc"   // Metal pigment effect
global_settings {assumed_gamma 1.0}   // set display gamma
background { color rgb <0.0,0.0,0.0> }   // set black background

camera {							// set view point (camera) location
    location <0, -50, -300>
    look_at  <-5, 0,  0>
    angle 90
}

light_source {						// set point light sources location
	< 0.0, 0, -10>
	rgb <1.000000, 1.000000, 1.000000> * 10.0     // set white light color and intensity
}

#declare R = 0.9;     // set radius value
#declare L = 1.4;  // set square area side
#declare X = 0.01;  // set co-ordinate x initial value
#declare Y = 0.01;  // set co-ordinate y initial value
#declare n = 200;    // set number of pixels per area side
#declare N = 10;   // set number of cycles

#for (p, -n, n, 1)
    #declare IncX = p*L/n;
    #for (q, -n, n, 1)
    #declare IncY = q*L/n;
    #declare X = IncX;
    #declare Y = IncY;
       #for (k,0,N)
       #declare XX = 3*X/4 - X*(X*X - 3*Y*Y)/(X*X + Y*Y)/(X*X + Y*Y)/
       (X*X + Y*Y)/4;
       #declare YY = 3*Y/4 - Y*(Y*Y - 3*X*X)/(X*X + Y*Y)/(X*X + Y*Y)/
       (X*X + Y*Y)/4;
       #declare X = XX;
       #declare Y = YY;
      #if (X*X+Y*Y > R)  // comment for full set
      #if (X*X+Y*Y < R+.05)
 	 sphere {
  	  < p, q, 0 >, 1
  	  	hollow
  		radiosity { importance 1.0 }
   		 texture {
    		  pigment { color Col_Glass_Yellow
    		}}
      	 finish { ambient rgb <0.3,0.1,0.1>
     		  diffuse .1
     		 reflection .1
     		 specular 1
     		}}

#end  // end if   // comment for full set
#end  // end if
#end  // end for k
#end  // end for q
#end  // end for p