POV Ray 3.7 code
//=================================
// Julia 3D set as a whole
// (POV-Ray cylindrical symmetry)
//=================================

#include "colors.inc"  // Standard Color definitions
#include "glass.inc"   //  Glass pigment effect
#include "metals.inc"   // Metal pigment effect
global_settings {assumed_gamma 1.0}   // set display gamma
background { color rgb <00,0.0,0.0> }    // set black background

camera {							// set view point (camera) location
    location <-20, 20, -300>
    look_at  <-5, 0,  0>
  }

light_source {						// set point light sources location
	< -50, 20, -10>
	rgb <1.000000, 1.000000, 1.000000> * 2.0     // set white light color and intensity
}

light_source {
	< 20, 20, -10>
	rgb <1.000000, 1.000000, 1.000000> * 2.0
}

#declare R = .1;     // set radius value
#declare L = 2;  // set square area side
#declare X = 0;  // set co-ordinate x initial value
#declare Y = 0;  // set co-ordinate y initial value
#declare Z = 0;  // set co-ordinate z initial value

#declare n = 200;    // set number of pixels per area side
#declare N = 30;   // set number of cycles
#declare Nr = 100;   // alternative  Nr = 25;   // set number of sections
#declare Th = -5;
#declare Ph = 20;

#declare Cx  = -0.7454294;    // set parameter c values
#declare Cy = 0;

union{ #for (p, -n, n, 1)
  #declare IncX = p*L/n;
  #for (q, -n, n, 1)
      #declare IncY = q*L/n;
      #declare X = IncX;
      #declare Y = IncY;
      #for (i,1,N)
      #declare XX = X*X - Y*Y  + Cx;
      #declare YY = 2*X*Y + Cy;
      #declare X = XX;
      #declare Y = YY;
       #if (X*X+Y*Y > R)
       #if (X*X+Y*Y < R+.005)
       #for (k,0,Nr)    //  replace n by n*clock for animation
 	 	sphere {
  		  < p, q*cos(3.14*k/Nr), q*sin(3.14*k/Nr) >, 1
  		// hollow
  		// radiosity { importance 1.0 }
   			 texture {
    			  pigment { color Col_Glass_Yellow }
      		 }
      		 finish { ambient rgb <0.3,0.1,0.1>
     			  diffuse .3
     			 reflection .3
     			 specular 1 }
   		}
#end  // end if
#end  // end if
#end  // end for k
#end  // end for i
#end  // end for q
#end  // end for p
rotate < 0, Th, Ph >}